­

If you want to clean up drawings with AutoCAD Architecture objects there are the commands exporttoautocad and AECTOACAD? (The AECEXPORTTOAUTOCAD command has been added to the Object Enabler in the software, enabling you to export a drawing to an AutoCAD format from within AutoCAD or other AutoCAD based vertical applications.)

DWG Convert also has the option to save with Exploded AEC Objects.

More Free AutoLISP and Visual LISP code snippets for AutoCAD

 Click here to download the code as a file.

 

;;; Read and write the settings in the "Explode AEC Objects" dialog box
;;; using the command _AecObjExplode
;;; The effect of writing this settings is directly affecting the command.
;;; By Jimmy Bergmark
;;; www.jtbworld.com
;;; For ADT 2004

;;; Reads the settings "Explode to anonymous blocks"
;;; (readAECObjectsExplodeOptions "Anonymous Block")
;;;   0 = Disable Explode to anonymous blocks
;;;   1 = Enable Explode to anonymous blocks
;;; (readAECObjectsExplodeOptions "Bind Xrefs")
;;;   0 = Don't bind xrefs
;;;   1 = Bind xrefs
;;; Others that can be used are:
;;; (readAECObjectsExplodeOptions "Bind Xrefs Bind Type")
;;; (readAECObjectsExplodeOptions "Erase AEC Objects")
;;; (readAECObjectsExplodeOptions "Explode AEC Objects")
;;; (readAECObjectsExplodeOptions "Include Model Tab")
;;; (readAECObjectsExplodeOptions "Maintain Properties")
;;; (readAECObjectsExplodeOptions "Name Length")
;;; (readAECObjectsExplodeOptions "Reuse Existing Names")
;;; (readAECObjectsExplodeOptions "Short Block Names")
;;; (readAECObjectsExplodeOptions "Verbose")
;;; (readAECObjectsExplodeOptions "Views")
(vl-load-com)
(defun readAECObjectsExplodeOptions (keyname)
  (vl-registry-read
    (strcat
      "HKEY_CURRENT_USER\\"
      (vlax-product-key)
      "\\Profiles\\"
      (vla-get-activeprofile
	(vla-get-profiles
	  (vla-get-preferences (vlax-get-acad-object))
	)
      )
      "\\Dialogs\\AecObjExplode40-Options"
    )
    keyname
  )
)


;;; Writes the settings "Explode to anonymous blocks"
;;; Disable Explode to anonymous blocks
;;;   (writeAECObjectsExplodeOptions "Anonymous Block" 0)
;;; Enable Explode to anonymous blocks
;;;   (writeAECObjectsExplodeOptions "Anonymous Block" 1)
;;; Don't bind xrefs
;;;   (writeAECObjectsExplodeOptions "Bind Xrefs" 0)
;;; Bind xrefs
;;;   (writeAECObjectsExplodeOptions "Bind Xrefs" 1)
;;; Others that can be used are:
;;; (writeAECObjectsExplodeOptions "Bind Xrefs Bind Type" 1)
;;; (writeAECObjectsExplodeOptions "Erase AEC Objects" 1)
;;; (writeAECObjectsExplodeOptions "Explode AEC Objects" 1)
;;; (writeAECObjectsExplodeOptions "Include Model Tab" 0)
;;; (writeAECObjectsExplodeOptions "Maintain Properties" 0)
;;; (writeAECObjectsExplodeOptions "Name Length" 31)
;;; (writeAECObjectsExplodeOptions "Reuse Existing Names" 0)
;;; (writeAECObjectsExplodeOptions "Short Block Names" 1)
;;; Display status messages
;;;   (writeAECObjectsExplodeOptions "Verbose" 1)
;;;   (writeAECObjectsExplodeOptions "Views" 0)
(defun writeAECObjectsExplodeOptions (keyname n)
  (vl-registry-write
    (strcat
      "HKEY_CURRENT_USER\\"
      (vlax-product-key)
      "\\Profiles\\"
      (vla-get-activeprofile
	(vla-get-profiles
	  (vla-get-preferences (vlax-get-acad-object))
	)
      )
      "\\Dialogs\\AecObjExplode40-Options"
    )
    keyname
    n
  )
)
Have any questions? Contact us

­